lundi 1 septembre 2014

Micro-rocket with Arduino data-logger



After several years of launching micro-rockets, I developed a data-logger based on Arduino platform that measures some flight parameters, such as maximum flight altitude, pressure, temperature...



The micro-rocket, the smallest of the family powered by solid propellant rocket motors, is extremely easy to do! The micro-rocket allows to learn safe flight conditions of a launcher. Using a cardboard tube, balsa and plastic plates, you can perform a micro-rocket rising more than 100 meters high!
It is then necessary to provide a parachute for reducing the lowering speed of the microrocket.

CNES and Planète Sciences regularly organize events to guide you in building and launching your microrockets: http://www.cnes-jeunes.fr/web/CNES-Jeunes-fr/8159-construire-et-lancer-une-microfusee.php

Micro-rocket characteristics:
Ogive + Electronics ~ 60grs
Micro rocket body + ailerons ~60grs
Total weight: ~120grs

Example of launch data:


Solid Propellant (D9-3 type) :

Some videos as example:


                           





From inboard camera (first try):                           

From smartphone:

From inboard camera (second try):  

 1 - Altitude: near 300m in 5s, average speed ~220km/h !!!!
  

 2 - Pressure: 



Solid Propellant (C6-3 type) :

Micro-rocket launch video:

1 - Altitude: near 150m in 2.5s, average speed ~220km/h !!!!


(Rq:  plotted as relative altitude / sea)
 2 - Pressure:


Some nice shots from sunday 29/01/2017




For the micro-rocket:
- CNES tube (1.8cm internal diameter)
- Aluminum paper
- Parts made with my 3D printer: 
o Rocket head containing electronics: http://www.thingiverse.com/thing:448665/#files
 


















For electronics:
- 1 micro SD card

  



NEW VERSION with Arduino Pro Mini:




Same as above except :
- 1 Pressure sensor BMP180: https://www.sparkfun.com/products/11824

---------------------------------------------------------------------------------------------------------------

The wiring is quite straightforward: 

SD Shield attached to SPI bus as follows:
 ** MOSI - pin 11
 ** MISO - pin 12
 ** CLK - pin 13
 ** CS - pin 10
 

BMP180 or BMP085 wiring
** SDA - A4
** SCL - A5
** VCC - 5V
** GND - GND


Li-Po battery (3.7V) directly plugged into the 5V pin. 

---------------------------------------------------------------------------------------------------------------
ARDUINO CODE:

/* BMP085 Extended Example Code
  by: Jim Lindblom
  SparkFun Electronics
  date: 1/18/11
  updated: 2/26/13
  license: CC BY-SA v3.0 - http://creativecommons.org/licenses/by-sa/3.0/
 
  Get pressure and temperature from the BMP085 and calculate
  altitude. Serial.print it out at 9600 baud to serial monitor.

  Update (7/19/11): I've heard folks may be encountering issues
  with this code, who're running an Arduino at 8MHz. If you're
  using an Arduino Pro 3.3V/8MHz, or the like, you may need to
  increase some of the delays in the bmp085ReadUP and
  bmp085ReadUT functions.

  Update J. Grisolia (2014)
  BMP180

 SD card datalogger
 This example shows how to log data from three analog sensors
 to an SD card using the SD library.
 The circuit:
 * analog sensors on analog ins 0, 1, and 2
 * SD card attached to SPI bus as follows:
 ** MOSI - pin 11
 ** MISO - pin 12
 ** CLK - pin 13
 ** CS - pin 10

Pins SDA & SCL
BMP085 wiring
** SDA - A4
** SCL - A5
** VCC - 5V
** GND - GND

*/

#include <Wire.h>
#include <SD.h>

#define DEBUG
//#define DEBUG_BMP085
int tempomesure = 25; //temporisation de la boucle
unsigned long t0=0;
unsigned long prevMillis=0;
//BMP085
#define BMP085_ADDRESS 0x77  // I2C address of BMP085, idem BMP1080
const unsigned char OSS = 0;  // Oversampling Setting
// Calibration values
int ac1;
int ac2;
int ac3;
unsigned int ac4;
unsigned int ac5;
unsigned int ac6;
int b1;
int b2;
int mb;
int mc;
int md;

// b5 is calculated in bmp085GetTemperature(...), this variable is also used in bmp085GetPressure(...)
// so ...Temperature(...) must be called before ...Pressure(...).
long b5;

short temperature;
long pressure;

// Use these for altitude conversions
const float p0 = 101325;     // Pressure at sea level (Pa)
float altitude;

//SD CARD
const int chipSelect = 10;

long fileNum = 0;  // maximum 99999
String fileName;
char name[13];
File dataFile;

void incFileNum() { // generate next file name:
  String s = "dat" + String(++fileNum) + ".txt";
  s.toCharArray(name,13);
}

void save(String s) {
  dataFile = SD.open(name, FILE_WRITE);
  if (dataFile) {
    dataFile.println(s);
    dataFile.close();
    Serial.println(s);
  } 
  else Serial.println("error opening " + String(name));
}

void setup()
{
  pinMode(chipSelect, OUTPUT);

  // Open serial communications and wait for port to open:
#if defined(DEBUG) || defined(DEBUG_BMP085)
  Serial.begin(115200);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for Leonardo only
  }
  Serial.print("Initializing SD card...");
  // make sure that the default chip select pin is set to
  // output, even if you don't use it:
  // see if the card is present and can be initialized:
  if (!SD.begin(chipSelect)) {
    Serial.println("Card failed, or not present");
    // don't do anything more:
    return;
  }
  Serial.println("card initialized.");
#endif
 //Efface le fichier initial
 // SD.remove("DATA.txt");

//GESTION DES NOMS DES FICHIERS
  //--------------------------------------------------
  incFileNum(); // set it to datxxxx.txt
  while (SD.exists(name)) incFileNum();

#ifdef DEBUG
  Serial.println("new file name: " + String(name));
#endif
  //--------------------------------------------------
  save("DATA MICRO FUSEES");
  save("t(ms)|Altitude(m)*100|Pression(Pa)|Temperature(C)*0.1");

//CAPTEUR bmp085
  Wire.begin();
  bmp085Calibration();
//initialisation du temps:
unsigned long prevMillis = millis();
}

void loop()
{
if ((millis() - prevMillis) > tempomesure) {
/////////////////////////////////////////////////////////////// 
//  Capteur pression et temperature
  temperature = bmp085GetTemperature(bmp085ReadUT());
  pressure = bmp085GetPressure(bmp085ReadUP());
  altitude = (float)44330 * (1 - pow(((float) pressure/p0), 0.190295));

#ifdef DEBUG_BMP085
  Serial.print("Temperature: ");
  Serial.print(temperature, DEC);
  Serial.println(" *0.1 deg C");
  Serial.print("Pressure: ");
  Serial.print(pressure, DEC);
  Serial.println(" Pa");
  Serial.print("Altitude: ");
  Serial.print(altitude, 2);
  Serial.println(" m");
  Serial.println();
#endif
  //delay(tempomesure);
///////////////////////////////////////////////////////////////
  // make a string for assembling the data to log:
 
  String dataString = "";
  //OLD
  //t0 = t0 + (millis() - prevMillis);
  //NEW
  t0 = millis();
/*
#ifdef DEBUG
  Serial.print("millis():");
  Serial.print(millis());
  Serial.print(",");
  Serial.print("t0:");
  Serial.print(t0);
  Serial.print(",");
#endif
 */
  unsigned int alti = altitude*100;
  unsigned long pressu = pressure;
  unsigned int tempe = temperature;
  dataString = String(t0) + "," + String(alti) + "," + String(pressu) + "," + String(tempe);
  // open the file. note that only one file can be open at a time,
  // so you have to close this one before opening another.
 
  //File dataFile = SD.open("DATA.txt", FILE_WRITE);
  File dataFile = SD.open(name, FILE_WRITE);

  // if the file is available, write to it:
  if (dataFile) {
    dataFile.println(dataString);
    dataFile.close();
    #ifdef DEBUG
        // print to the serial port too:
      Serial.println(dataString);
    #endif   
  } 
  // if the file isn't open, pop up an error:
  else {
    Serial.println("error opening datalog.txt");
  }//fin du if dataFile
  prevMillis = millis();
}
 
}// fin de loop

//---------------------------------------------------------------------------------------------------------------
//---------------------------------------------------------------------------------------------------------------

// Stores all of the bmp085's calibration values into global variables
// Calibration values are required to calculate temp and pressure
// This function should be called at the beginning of the program
void bmp085Calibration()
{
  ac1 = bmp085ReadInt(0xAA);
  ac2 = bmp085ReadInt(0xAC);
  ac3 = bmp085ReadInt(0xAE);
  ac4 = bmp085ReadInt(0xB0);
  ac5 = bmp085ReadInt(0xB2);
  ac6 = bmp085ReadInt(0xB4);
  b1 = bmp085ReadInt(0xB6);
  b2 = bmp085ReadInt(0xB8);
  mb = bmp085ReadInt(0xBA);
  mc = bmp085ReadInt(0xBC);
  md = bmp085ReadInt(0xBE);
}

// Calculate temperature given ut.
// Value returned will be in units of 0.1 deg C
short bmp085GetTemperature(unsigned int ut)
{
  long x1, x2;
 
  x1 = (((long)ut - (long)ac6)*(long)ac5) >> 15;
  x2 = ((long)mc << 11)/(x1 + md);
  b5 = x1 + x2;

  return ((b5 + 8)>>4); 
}

// Calculate pressure given up
// calibration values must be known
// b5 is also required so bmp085GetTemperature(...) must be called first.
// Value returned will be pressure in units of Pa.
long bmp085GetPressure(unsigned long up)
{
  long x1, x2, x3, b3, b6, p;
  unsigned long b4, b7;
 
  b6 = b5 - 4000;
  // Calculate B3
  x1 = (b2 * (b6 * b6)>>12)>>11;
  x2 = (ac2 * b6)>>11;
  x3 = x1 + x2;
  b3 = (((((long)ac1)*4 + x3)<<OSS) + 2)>>2;
 
  // Calculate B4
  x1 = (ac3 * b6)>>13;
  x2 = (b1 * ((b6 * b6)>>12))>>16;
  x3 = ((x1 + x2) + 2)>>2;
  b4 = (ac4 * (unsigned long)(x3 + 32768))>>15;
 
  b7 = ((unsigned long)(up - b3) * (50000>>OSS));
  if (b7 < 0x80000000)
    p = (b7<<1)/b4;
  else
    p = (b7/b4)<<1;
   
  x1 = (p>>8) * (p>>8);
  x1 = (x1 * 3038)>>16;
  x2 = (-7357 * p)>>16;
  p += (x1 + x2 + 3791)>>4;
 
  return p;
}

// Read 1 byte from the BMP085 at 'address'
char bmp085Read(unsigned char address)
{
  unsigned char data;
 
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(address);
  Wire.endTransmission();
 
  Wire.requestFrom(BMP085_ADDRESS, 1);
  while(!Wire.available())
    ;
   
  return Wire.read();
}

// Read 2 bytes from the BMP085
// First byte will be from 'address'
// Second byte will be from 'address'+1
int bmp085ReadInt(unsigned char address)
{
  unsigned char msb, lsb;
 
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(address);
  Wire.endTransmission();
 
  Wire.requestFrom(BMP085_ADDRESS, 2);
  while(Wire.available()<2)
    ;
  msb = Wire.read();
  lsb = Wire.read();
 
  return (int) msb<<8 | lsb;
}

// Read the uncompensated temperature value
unsigned int bmp085ReadUT()
{
  unsigned int ut;
 
  // Write 0x2E into Register 0xF4
  // This requests a temperature reading
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF4);
  Wire.write(0x2E);
  Wire.endTransmission();
 
  // Wait at least 4.5ms
  delay(5);
 
  // Read two bytes from registers 0xF6 and 0xF7
  ut = bmp085ReadInt(0xF6);
  return ut;
}

// Read the uncompensated pressure value
unsigned long bmp085ReadUP()
{
  unsigned char msb, lsb, xlsb;
  unsigned long up = 0;
 
  // Write 0x34+(OSS<<6) into register 0xF4
  // Request a pressure reading w/ oversampling setting
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF4);
  Wire.write(0x34 + (OSS<<6));
  Wire.endTransmission();
 
  // Wait for conversion, delay time dependent on OSS
  delay(2 + (3<<OSS));
 
  // Read register 0xF6 (MSB), 0xF7 (LSB), and 0xF8 (XLSB)
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF6);
  Wire.endTransmission();
  Wire.requestFrom(BMP085_ADDRESS, 3);
 
  // Wait for data to become available
  while(Wire.available() < 3)
    ;
  msb = Wire.read();
  lsb = Wire.read();
  xlsb = Wire.read();
 
  up = (((unsigned long) msb << 16) | ((unsigned long) lsb << 8) | (unsigned long) xlsb) >> (8-OSS);
 
  return up;
}

10 commentaires:

  1. Is the code supplied compatible with BMP180? what libraries to install?
    Do you have electric schematics?
    How to add control over a servo (PWM) to trigger at apogee for parachute release (when altitude starts decreasing)?

    RépondreSupprimer
    Réponses
    1. Hi Hugo, this code works with BMP180?

      Supprimer
    2. I did not use this code, just pieces of code from arduino examples to read data from BMP180 and to write it to SD Card.
      It worked, but never got to apply it to a rocket and trigger the parachute with it

      Supprimer
    3. Hi, Hugo!... i just have tha arduino nano, the SDCard and the BMP180... i try this code but ir fail ... can you help me please?

      Supprimer
    4. This is not working code. This is the last draft I had in backup:

      /* BMP085 code based on Jim Lindblom date: 1/18/11 updated: 2/26/13
      license: CC BY-SA v3.0 - http://creativecommons.org/licenses/by-sa/3.0/
      Update (7/19/11): If you're using an Arduino Pro 3.3V/8MHz, you may need to increase some of the delays in the bmp085ReadUP and bmp085ReadUT functions.
      BMP085 wiring
      ** SDA - A4
      ** SCL - A5
      ** VCC - 5V
      ** GND - GND

      SD card datalogger - log data from three analog sensors to an SD card using the SD library.
      * analog sensors on analog ins 0, 1, and 2
      * SD card attached to SPI bus:
      ** MOSI - pin 11
      ** MISO - pin 12
      ** CLK - pin 13
      ** CS - pin 10

      Created 22 April 2007 By David A. Mellis modified 9 Apr 2012 by Tom Igoe
      http://home.earthlink.net/~david.schultz/rnd/2002/KalmanApogee.pdf
      Reads repeatedly from an analog input, calculating a running average and printing it to the computer. Keeps ten readings in an array and continually averages them. http://www.arduino.cc/en/Tutorial/Smoothing
      * Analog sensor (potentiometer will do) attached to analog input 0
      */

      #include
      #include
      #include
      #include

      #define DEBUG
      //#define DEBUG_BMP085
      int tempomesure = 25; //timming of mesurement
      unsigned long t0 = 0;
      unsigned long prevMillis = 0;

      //BMP085
      #define BMP085_ADDRESS 0x77 // I2C address of BMP085, idem BMP1080
      const unsigned char OSS = 0; // Oversampling Setting

      // Calibration values
      int ac1;
      int ac2;
      int ac3;
      unsigned int ac4;
      unsigned int ac5;
      unsigned int ac6;
      int b1;
      int b2;
      int mb;
      int mc;
      int md;

      // b5 is calculated in bmp085GetTemperature(...), this variable is also used in bmp085GetPressure(...)
      // so ...Temperature(...) must be called before ...Pressure(...).
      long b5;
      short temperature;
      long pressure;

      // Use these for altitude conversions
      const float p0 = 101325; // Pressure at sea level (Pa)
      float altitude;

      //SD CARD
      const int chipSelect = 10;
      long fileNum = 0; // maximum 99999
      String fileName;
      char name[13];
      File dataFile;

      void incFileNum() { // generate next file name:
      String s = "dat" + String(++fileNum) + ".txt";
      s.toCharArray(name, 13);
      }

      Supprimer
    5. void save(String s) {
      dataFile = SD.open(name, FILE_WRITE);
      if (dataFile) {
      dataFile.println(s);
      dataFile.close();
      Serial.println(s);
      }
      else Serial.println("error opening " + String(name));
      }

      //Calculo e Servo
      Servo myservo; // create servo object to control a servo

      //DATA SMOOTHING
      // Define the number of samples to keep track of. The higher the number,
      // the more the readings will be smoothed, but the slower the output will
      // respond to the input. Using a constant rather than a normal variable lets
      // use this value to determine the size of the readings array.
      const int numReadings = 10;
      int readings[numReadings]; // the readings from the analog input
      int readIndex = 0; // the index of the current reading
      int total = 0; // the running total
      int average = 0; // the average


      void setup()
      {
      pinMode(chipSelect, OUTPUT);

      //SERVO
      myservo.attach(9); // attaches the servo on pin 9 to the servo object
      myservo.write(0); //posição do servo a 0

      // Open serial communications and wait for port to open:
      #if defined(DEBUG) || defined(DEBUG_BMP085)
      Serial.begin(115200);
      while (!Serial) {
      ; // wait for serial port to connect. Needed for Leonardo only
      }
      Serial.print("Initializing SD card...");
      // make sure that the default chip select pin is set to
      // output, even if you don't use it:
      // see if the card is present and can be initialized:
      if (!SD.begin(chipSelect)) {
      Serial.println("Card failed, or not present");
      // don't do anything more:
      return;
      }
      Serial.println("card initialized.");
      #endif
      //Efface le fichier initial
      // SD.remove("DATA.txt");

      //GESTION DES NOMS DES FICHIERS
      //--------------------------------------------------
      incFileNum(); // set it to datxxxx.txt
      while (SD.exists(name)) incFileNum();

      #ifdef DEBUG
      Serial.println("new file name: " + String(name));
      #endif
      //--------------------------------------------------
      save("DATA MICRO FUSEES");
      save("t(ms)|Altitude(m)*100|Pression(Pa)|Temperature(C)*0.1");

      //CAPTEUR bmp085
      Wire.begin();
      bmp085Calibration();
      //initialisation du temps:
      unsigned long prevMillis = millis();

      // CALCULO initialize all the readings to 0:
      for (int thisReading = 0; thisReading < numReadings; thisReading++) {
      readings[thisReading] = 0;}
      }

      void loop()
      {
      if ((millis() - prevMillis) > tempomesure) {
      // Capteur pression et temperature
      temperature = bmp085GetTemperature(bmp085ReadUT());
      pressure = bmp085GetPressure(bmp085ReadUP());
      altitude = (float)44330 * (1 - pow(((float) pressure / p0), 0.190295));

      #ifdef DEBUG_BMP085
      Serial.print("Temperature: ");
      Serial.print(temperature, DEC);
      Serial.println(" *0.1 deg C");
      Serial.print("Pressure: ");
      Serial.print(pressure, DEC);
      Serial.println(" Pa");
      Serial.print("Altitude: ");
      Serial.print(altitude, 2);
      Serial.println(" m");
      Serial.println();
      #endif
      //delay(tempomesure);
      // make a string for assembling the data to log:

      String dataString = "";
      //OLD
      //t0 = t0 + (millis() - prevMillis);
      //NEW
      t0 = millis();
      /*
      #ifdef DEBUG
      Serial.print("millis():");
      Serial.print(millis());
      Serial.print(",");
      Serial.print("t0:");
      Serial.print(t0);
      Serial.print(",");
      #endif
      */
      unsigned int alti = altitude * 100;
      unsigned long pressu = pressure;
      unsigned int tempe = temperature;
      dataString = String(t0) + "," + String(alti) + "," + String(pressu) + "," + String(tempe);
      // open the file. note that only one file can be open at a time,
      // so you have to close this one before opening another.

      //File dataFile = SD.open("DATA.txt", FILE_WRITE);
      File dataFile = SD.open(name, FILE_WRITE);

      Supprimer
    6. // if the file is available, write to it:
      if (dataFile) {
      dataFile.println(dataString);
      dataFile.close();
      #ifdef DEBUG
      // print to the serial port too:
      Serial.println(dataString);
      #endif
      }
      // if the file isn't open, pop up an error:
      else {
      Serial.println("error opening datalog.txt");
      }//fin du if dataFile
      prevMillis = millis();
      }

      //Definir a posição do servo
      myservo.write(180); // sets the servo position

      // subtract the last reading:
      total = total - readings[readIndex];
      // read from the sensor:
      readings[readIndex] = altitude;
      // add the reading to the total:
      total = total + readings[readIndex];
      // advance to the next position in the array:
      readIndex = readIndex + 1;

      // if we're at the end of the array...
      if (readIndex >= numReadings) {
      // ...wrap around to the beginning:
      readIndex = 0;
      }

      // calculate the average:
      average = total / numReadings;
      // send it to the computer as ASCII digits
      Serial.println(average);
      delay(1); // delay in between reads for stability

      }// fin de loop

      //---------------------------------------------------------------------------------------------------------------
      //---------------------------------------------------------------------------------------------------------------

      // Stores all of the bmp085's calibration values into global variables
      // Calibration values are required to calculate temp and pressure
      // This function should be called at the beginning of the program
      void bmp085Calibration()
      {
      ac1 = bmp085ReadInt(0xAA);
      ac2 = bmp085ReadInt(0xAC);
      ac3 = bmp085ReadInt(0xAE);
      ac4 = bmp085ReadInt(0xB0);
      ac5 = bmp085ReadInt(0xB2);
      ac6 = bmp085ReadInt(0xB4);
      b1 = bmp085ReadInt(0xB6);
      b2 = bmp085ReadInt(0xB8);
      mb = bmp085ReadInt(0xBA);
      mc = bmp085ReadInt(0xBC);
      md = bmp085ReadInt(0xBE);
      }

      // Calculate temperature given ut.
      // Value returned will be in units of 0.1 deg C
      short bmp085GetTemperature(unsigned int ut)
      {
      long x1, x2;

      x1 = (((long)ut - (long)ac6) * (long)ac5) >> 15;
      x2 = ((long)mc << 11) / (x1 + md);
      b5 = x1 + x2;

      return ((b5 + 8) >> 4);
      }

      // Calculate pressure given up
      // calibration values must be known
      // b5 is also required so bmp085GetTemperature(...) must be called first.
      // Value returned will be pressure in units of Pa.
      long bmp085GetPressure(unsigned long up)
      {
      long x1, x2, x3, b3, b6, p;
      unsigned long b4, b7;

      b6 = b5 - 4000;
      // Calculate B3
      x1 = (b2 * (b6 * b6) >> 12) >> 11;
      x2 = (ac2 * b6) >> 11;
      x3 = x1 + x2;
      b3 = (((((long)ac1) * 4 + x3) << OSS) + 2) >> 2;

      Supprimer
    7. // Calculate B4
      x1 = (ac3 * b6) >> 13;
      x2 = (b1 * ((b6 * b6) >> 12)) >> 16;
      x3 = ((x1 + x2) + 2) >> 2;
      b4 = (ac4 * (unsigned long)(x3 + 32768)) >> 15;

      b7 = ((unsigned long)(up - b3) * (50000 >> OSS));
      if (b7 < 0x80000000)
      p = (b7 << 1) / b4;
      else
      p = (b7 / b4) << 1;

      x1 = (p >> 8) * (p >> 8);
      x1 = (x1 * 3038) >> 16;
      x2 = (-7357 * p) >> 16;
      p += (x1 + x2 + 3791) >> 4;

      return p;
      }

      // Read 1 byte from the BMP085 at 'address'
      char bmp085Read(unsigned char address)
      {
      unsigned char data;

      Wire.beginTransmission(BMP085_ADDRESS);
      Wire.write(address);
      Wire.endTransmission();

      Wire.requestFrom(BMP085_ADDRESS, 1);
      while (!Wire.available())
      ;

      return Wire.read();
      }

      // Read 2 bytes from the BMP085
      // First byte will be from 'address'
      // Second byte will be from 'address'+1
      int bmp085ReadInt(unsigned char address)
      {
      unsigned char msb, lsb;

      Wire.beginTransmission(BMP085_ADDRESS);
      Wire.write(address);
      Wire.endTransmission();

      Wire.requestFrom(BMP085_ADDRESS, 2);
      while (Wire.available() < 2)
      ;
      msb = Wire.read();
      lsb = Wire.read();

      return (int) msb << 8 | lsb;
      }

      // Read the uncompensated temperature value
      unsigned int bmp085ReadUT()
      {
      unsigned int ut;

      // Write 0x2E into Register 0xF4
      // This requests a temperature reading
      Wire.beginTransmission(BMP085_ADDRESS);
      Wire.write(0xF4);
      Wire.write(0x2E);
      Wire.endTransmission();

      // Wait at least 4.5ms
      delay(5);

      // Read two bytes from registers 0xF6 and 0xF7
      ut = bmp085ReadInt(0xF6);
      return ut;
      }

      // Read the uncompensated pressure value
      unsigned long bmp085ReadUP()
      {
      unsigned char msb, lsb, xlsb;
      unsigned long up = 0;

      // Write 0x34+(OSS<<6) into register 0xF4
      // Request a pressure reading w/ oversampling setting
      Wire.beginTransmission(BMP085_ADDRESS);
      Wire.write(0xF4);
      Wire.write(0x34 + (OSS << 6));
      Wire.endTransmission();

      // Wait for conversion, delay time dependent on OSS
      delay(2 + (3 << OSS));

      // Read register 0xF6 (MSB), 0xF7 (LSB), and 0xF8 (XLSB)
      Wire.beginTransmission(BMP085_ADDRESS);
      Wire.write(0xF6);
      Wire.endTransmission();
      Wire.requestFrom(BMP085_ADDRESS, 3);

      // Wait for data to become available
      while (Wire.available() < 3)
      ;
      msb = Wire.read();
      lsb = Wire.read();
      xlsb = Wire.read();

      up = (((unsigned long) msb << 16) | ((unsigned long) lsb << 8) | (unsigned long) xlsb) >> (8 - OSS);

      return up;
      }

      Supprimer
  2. Thanks so much for your work! Works very well!

    RépondreSupprimer
  3. it works with the BMP180?, thanks!

    RépondreSupprimer